win-disk-partition（windowsのディスク パーティション構成）
update 2016-03-21
環境

windows

要約

windowsのディスク パーティション構成について簡略にまとめた。

文章、画像についてはマイクロソフトのサイトを引用したものである
BIOS ベースの推奨ディスク パーティション構成
https://technet.microsoft.com/ja-jp/library/dd744364%28v=ws.10%29.aspx
Unified Extensible Firmware Interface (UEFI) ベースのコンピューターに推奨されるディスク パーティションの構成
https://technet.microsoft.com/ja-jp/library/dd744301%28v=ws.10%29.aspx

作成例 １ (最後部に回復パーティションを作成する例である)
作成例 ２ (データパーティションを追加して、最後部に回復パーティションを作成する例である)
作成例 ３ (MSRを作成しないでインストールする例である)

BIOS ベースのディスク パーティション構成

既定の構成
IC310040.gif
diskpartコマンドによる作成
select disk 0
clean
create partition primary size=300
format quick fs=ntfs label="System"
assign letter="S"
create partition primary
format quick fs=ntfs label="Windows"
assign letter="W"
exit
システムの回復用の"Recovery"パーティションを持った構成
IC310064.gif
diskpartコマンドによる作成
select disk 0
clean
create partition primary size=3000
format quick fs=ntfs label="Recovery"
assign letter="R"
set id=27
create partition primary size=300
format quick fs=ntfs label="System"
assign letter="S"
active
create partition primary
format quick fs=ntfs label="Windows"
assign letter="W"
exit
5つ以上のパーティションを持った構成
IC310041.gif
diskpartコマンドによる作成
select disk 0
clean
create partition primary size=3000
format quick fs=ntfs label="Recovery"
assign letter="R"
set id=27
create partition primary size=250
format quick fs=ntfs label="Utility2"
assign letter="U"
set id=27
create partition primary size=100
format quick fs=ntfs label="System"
assign letter="S"
active
create partition extended
create partition logical
format quick fs=ntfs label="Windows"
assign letter="W"
create partition logical
format quick fs=ntfs label="Logical2"
assign letter="L"
exit

単一 パーティションの使用
single-partition.jpg
diskpartコマンドによる作成

select disk 0
clean
create partition primary
format quick fs=ntfs label="Windows"
assign letter="C"
exit

UEFI ベースのディスク パーティション構成

既定の構成
IC310042.gif
※MSR:Microsoft reserved partition (Microsoft 予約パーティション)
MSRパーティションはGPTディスクに変換した時点で自動的に作成される(MBRディスクに変換すると削除される)
MSRは作成時にサイズ設定できる。
MSRにはドライブレターを付けることはできない。
MSRは強制的に削除できる( diskpart にて partitionを指定して delete partition override で削除できる)

diskpartコマンドによる作成
select disk 0
clean
convert gpt
create partition efi size=100
format quick fs=fat32 label="System" //EFI system partition
assign letter="S"
create partition msr size=128 //MSR:Microsoft reserved partition (Microsoft 予約パーティション)
create partition primary
format quick fs=ntfs label="Windows"  //Windowsをインストールするpartition
assign letter="W"
exit
システムの回復用の"Recovery"パーティションを持った構成
IC310057.gif
※MSR:Microsoft reserved partition (Microsoft 予約パーティション)
diskpartコマンドによる作成
select disk 0
clean
convert gpt
create partition primary size=450

format quick fs=ntfs label="Recovery"  //RECOVERY parttion
set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac" //このidは固定
assign letter="R"
create partition efi size=100
format quick fs=fat32 label="System"  //EFI system partition
assign letter="S"
create partition msr size=128  //MSR:Microsoft reserved partition (Microsoft 予約パーティション)
create partition primary
format quick fs=ntfs label="Windows"  //Windowsをインストールするpartition
assign letter="W"
exit

作成例 １	先頭へ戻る
最後部に1024MBの回復パーティションを作成
Windowsパーティションをshrink(縮小)して回復パーティションを作成する。
example1.jpg
diskpartコマンドによる作成

list disk  //接続されているディスクを確認
select disk 0
clean
convert gpt
create partition efi size=100
format quick fs=fat32 label="System" //EFI system partition
assign letter="S"
create partition msr size=16 //MSR:Microsoft reserved partition (Microsoft 予約パーティション)
create partition primary  //残りの領域はいったん全てWindowsパーティションとして作成
format quick fs=ntfs label="Windows"  //Windowsをインストールするpartition
assign letter="W"

list partition  //パーティションを確認
select partition 3  //shrink(縮小)する対象として3番目のパーティション(Windowsパーティション)を指定する
shrink desired=1024  //ボリュームサイズから縮小する領域のサイズをMB単位で指定
create partition primary  //空いた領域のすべてを回復パーティションとして割り当てる
format quick fs=ntfs label="Recovery"  //RECOVERY parttion
set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac" //このidは固定
assign letter="R"

list partition  //作成したパーティションを確認
list volume   //作成したドライブレターを確認
exit

作成例 ２	先頭へ戻る
Windowsパーティションの後部にDATAパーティションを作成する。
DATAパーティションをshrink(縮小)して、最後部に1024MBの回復パーティションを作成する。
example2.jpg 
diskpartコマンドによる作成

list disk  //接続されているディスクを確認
select disk 0
clean
convert gpt
create partition efi size=100
format quick fs=fat32 label="System" //EFI system partition
assign letter="S"
create partition msr size=16 //MSR:Microsoft reserved partition (Microsoft 予約パーティション)
create partition primary size=81920 //Windowsパーティション80GB(80GB x 1024MB=81920MB)を作成
format quick fs=ntfs label="Windows"  //Windowsをインストールするpartition
assign letter="W"
create partition primary  //残りの領域はいったんDATAパーティションとして作成
format quick fs=ntfs label="Data"  //Dataパーティションを作成
assign letter="Y"

list partition  //パーティションを確認
select partition 4  //shrink(縮小)する対象として4番目のパーティション(Dataパーティション)を指定する
shrink desired=1024  //ボリュームサイズから縮小する領域のサイズをMB単位で指定
create partition primary  //空いた領域のすべてを回復パーティションとして割り当てる
format quick fs=ntfs label="Recovery"  //RECOVERY parttion
set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac" //このidは固定
assign letter="R"

list partition  //作成したパーティションを確認
list volume   //作成したドライブレターを確認
exit

作成例 ３ (MSRを作成しない例)  先頭へ戻る
example3.jpg
diskpartコマンドによる作成

list disk  //接続されているディスクを確認
select disk 0
clean
convert gpt
create partition efi size=100
format quick fs=fat32 label="System" //EFI system partition
assign letter="S"
create partition primary  //残りの領域はいったん全てWindowsパーティションとして作成
format quick fs=ntfs label="Windows"  //Windowsをインストールするpartition
assign letter="W"

list partition  //パーティションを確認
select partition 2  //shrink(縮小)する対象として2番目のパーティション(Windowsパーティション)を指定する
shrink desired=1024  //ボリュームサイズから縮小する領域のサイズをMB単位で指定
create partition primary  //空いた領域のすべてを回復パーティションとして割り当てる
format quick fs=ntfs label="Recovery"  //RECOVERY parttion
set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac" //このidは固定
assign letter="R"

list partition  //作成したパーティションを確認
list volume   //作成したドライブレターを確認
exit

Windowsインストール時には下図のようにパーティションが表示される。
msr_non.jpg

end of list